dtmt_AutoCue.bat
↓↓ここから↓↓
@echo off
rem DeamonTools Ultra でCDイメージをマウントするバッチ
rem # イメージファイル本体が同名で、拡張子.cue があれば、優先してマウント。
rem usage @:> dtmt_AutoCuew.bat <Drive> [<ImgPath>]
rem <Drive> : マウント先ドライブレター
rem <ImgPath> : ディスクイメージ
rem 省略するとアンマウントして終了
rem ちなみに DaemonTools のコマンド（詳しくは DTCommandLine.exe -help）
rem DTCommandLine.exe --mount --type <Type> --letter <Letter> --ro --path <ImgPath>
rem DTCommandLine.exe -m -t <Type> -l <Letter> --ro -p <ImgPath>
rem <Type> : "dt" or "scsi" or "ide"
rem <Letter> : ドライブレター
rem 例）DTCommandLine.exe --mount "scsi" --letter "P" -ro --path "C:\image.iso"
rem DTCommandLine.exe --unmount --letter <Letter>
rem 例）DTCommandLine.exe --unmount --letter "P"
rem ダブルクォーテーション除去
set ORG_FN=%~2
set DT_DEV_TYPE=dt
rem 引数1（ドライブ）が無ければ終了へ
if "%1" == "" goto quit
rem コロン除去
set DT_DRV_LETTER=%1
set DT_DRV_LETTER=%DT_DRV_LETTER:~0,1%
rem DaemonToolsにパスを通す
path %PATH%;C:\Program Files\DAEMON Tools Ultra\
rem アンマウント
echo 仮想ドライブ %1 をアンマウントしています
DTCommandLine.exe --unmount --letter "%DT_DRV_LETTER%"
rem 引数2（ファイルパス）が無ければ終了へ
if "%ORG_FN%" == "" goto quit
rem イメージをマウント
set CUE_FN="%~d2%~p2%~n2.cue"
if exist %CUE_FN% ( set FN=%CUE_FN% ) else set FN="%ORG_FN%"
echo %FN% をマウントします
DTCommandLine.exe --mount --type "%DT_DEV_TYPE%" --letter "%DT_DRV_LETTER%" --ro --path "%FN%"
set ORG_FN=
set CUE_FN=
set FN=
set DT_DEV_TYPE=
set DT_DRV_LETTER=
:quit
↑↑ここまで↑↑